Title – Famicom Daisakusen Family Basic Step Game
System – Nintendo Family BASIC
Author – Unknown
Publication – Famicom Daisakusen Family Basic Step (ファミコン大作戦 ファミリーベーシック ステップ)
Page Scans – 1 2 3 4
Preserved By – ozidual
Recommended Emulator – VirtualNES
Preserver’s Notes:
The game is played entirely with the D-Pad. The map starts empty with some walls. Move Penpen around the room to fill it up with apples, and increase your score. The fly will always move toward Penpen (while Penpen is moving). If Penpen is caught by the fly, the game is over.
The book, Famicom Daisakusen Family Basic Step, is the 2nd out of 3 in a series that teaches Family Basic. This game is the culmination of the second book.
Code:
100 SPRITE ON:CLS:VIEW
110 SC=0:SE=406
150 GOTO 300
200 FOR I=1 TO 27:FOR J=1 TO 19:IF SCR$(I,J)=CHR$(215) THEN LOCATE I,J:PRINT ” “;
210 NEXT:NEXT
230 I=RND(24)+2:J=RND(15)+4
250 IF SCR$(I,J)<>” ” THEN 230
270 LOCATE I,J:PRINT CHR$(221);:SE=SE-1
280 LOCATE 10,23:PRINT” “;
300 SD=SE:POSITION 4,24,32
310 POSITION 2,216,32
400 V=STICK(0):N=4
410 IF V=8 THEN V=1:GOTO 500
420 IF V=1 THEN V=3:GOTO 500
430 IF V=4 THEN V=5:GOTO 500
440 IF V=2 THEN V=7:GOTO 500
450 V=0:GOTO 510
500 GOSUB 6000
510 IF F=0 OR V=0 THEN GOSUB 5000
600 X=XPOS(4)/8-2
610 Y=YPOS(4)/8-3
620 FOR I=X TO X+1:FOR J=Y TO Y+1
630 IF SCR$(I,J)=” ” THEN LOCATE I,J:PRINT CHR$(215);:SD=SD-1:SC=SC+1
640 NEXT:NEXT
650 IF SD<1 THEN 2000
700 N=2:V=3+SGN(YPOS(4)-YPOS(2))*2:IF V<>3 THEN GOSUB 6000:IF F=0 THEN 750
710 V=5+SGN(XPOS(2)-XPOS(4))*2:IF V<>5 THEN GOSUB 6000:IF F=0 THEN 750
720 GOTO 760
750 IF RND(100)<80 THEN 800
760 V=RND(4)*2+1
770 GOSUB 6000:IF F=1 THEN V=0
800 GOSUB 5000
850 IF XPOS(2)<XPOS(4)+11 AND XPOS(2)>XPOS(4)-11 AND YPOS(2)<YPOS(4)+11 AND YPOS(2)>YPOS(4)-11 THEN 3000
950 GOSUB 7000
999 GOTO 400
2000 GOSUB 7000
2050 LOCATE 10,23:PRINT “GOOD !”;
2100 GOTO 200
3000 BEEP:PAUSE 230:BEEP:CLS:SPRITE OFF
3010 LOCATE 7,10:PRINT “SCORE =”;SC
3020 LOCATE 5,13:PRINT “HIT ANY KEY !”
3030 PAUSE
3040 RUN
3100 END
5000 DEF MOVE(N)=SPRITE(N,V,1,4):MOVE N:RETURN
6000 F=0:X=XPOS(N)/8-2:IF V=3 OR V=7 THEN X=X+SGN(5-V)
6010 Y=YPOS(N)/8-3:IF V=1 ORV=5 THEN Y=Y+SGN(V-3)
6050 FOR I=X TO X+1:FOR J=Y TO Y+1
6060 IF SCR$(I,J)>CHR$(221) AND SCR$(I,J)<CHR$(232) THEN F=1
6070 IF N=4 AND SCR$(I,J)=CHR$(221) THEN F=1
6080 NEXT:NEXT:RETURN
7000 LOCATE 8,21:PRINT “SCORE =”;SC;:RETURN
