Title: スターチェイサー (Starchaser)
System: Family Basic
Author: 
Publication: ファミリーコンピュータゲーム攻略㊙︎テクニック (Family Computer Game Strategy Secret Techniques)
Page Scans: 
Preserved By: ozidual
Recommended Emulator: VirtualNES

Article Translation

Your role this time is to become a lone wolf in space and defeat the enemy. However, this is a completely different space from Earth. You can only see the enemy vaguely.
Despite your big handicaps, you decide to take your state-of-the-art spaceship and fight the bad guys. The enemy also attacks you with high-powered spaceships. It's a test of skill. Who will win the one-on-one battle? Now it's getting fun--.
However, the beam cannon installed on your spaceship is not very powerful. On the other hand, the enemy's beam is quite powerful. The enemy's beam works even from a distance, but your beam must be fired directly above the enemy. You're at a disadvantage again!
But don't be discouraged. The enemies aren't very smart, so you can use that to your advantage and get close to them with ease. The only problem is that it's hard to see the enemies. The background color of the spaceship keeps changing, hiding the enemy. But it's not like you can't see them at all. You can see them just enough to get a sense that "Ah. I think they're over there."
Just shoot right there. Stand directly above the enemy and press the A button. If you hit it, you get 10 points. You score will keep increasing until you are killed.
This game is a spaceship battle game, but if you don't like that, you can play with other characters. Mario and Mr. Fly, Lady and Penpen, try making your own original character by referring to Character Table A. Just change the SPRITE command and you're good to go. Once you get used to it, it's an easy change to make, so why not give it a try?


Code

10 VIEW:X=120:Y=120:SPRITE ON:SUBH=2:HAN=0:N=0:BOMT=2:SC=0:SP=0
20 CGSET 0,1
30 GOSUB 200
40 LOCATE 10,21:PRINT "SCORE  0"
60 S=STICK(0)
80 IF S=1 AND X<220 THEN N=3:GOSUB 200:GOTO 140
90 IF S=2 AND X>30  THEN N=7:GOSUB 200:GOTO 140
100 IF S=4 AND Y<170 THEN N=5:GOSUB 200:GOTO 140
110 IF S=8 AND Y>30  THEN N=1:GOSUB 200
140 GOSUB 700
150 GOSUB 300
160 GOSUB 400
170 PALETB SP,15,16,CK+SP,CK+SP
180 SP=SP+1:IF SP=4 THEN SP=0:CK=CK+1:IF CK>&H60 THEN CK=0
190 X=XPOS(0):Y=YPOS(0):GOTO 60
200 DEF MOVE(0)=SPRITE(8,N,1,9 ,0,0)
210 POSITION 0,X,Y:MOVE 0
290 RETURN
300 IF (X/16=XPOS(1)/16)AND(Y/16=YPOS(1)/16)AND SUBH=0 THEN PLAY"T1O3C":GOTO 320
310 IF (X/50=XPOS(1)/50)AND(Y/50=YPOS(1)/50)AND SUBH=0 THEN PLAY"T1O5B"
320 SX=XPOS(1):SY=YPOS(1)
330 IF SUBH=1 THEN SX=RND(100)+50:SY=RND(100)+50
340 IF (RND(10)=5 AND SUBH=0)OR SUBH=1 THEN SF=RND(7)+1:DEF MOVE(1)=SPRITE(7,SF,RND(3)+4,30,1,0):POSITION 1,SX,SY
350 MOVE 1:K=1:GOTO 800
390 RETURN
400 FOR I=2 TO 7
410 K=I:GOSUB 800
420 IF MOVE(I)=0 THEN DEF MOVE(I)=SPRITE(12,0,0,0,0,0):POSITION I,0,0:ERA I:GOTO 440
430 IF (X/15 = XPOS(I)/15) AND (Y/15 =YPOS(I)/15) THEN HAN=1
440 NEXT
450 IF HAN=1 THEN 600
460 IF RND(10)=5 AND SUBH=0 THEN GOSUB 500
490 RETURN
500 FOR I=2 TO 7
510 IF MOVE(I)=0 THEN DEF MOVE(I) =SPRITE(12,SF,1,50 ,0,0):POSITION I,XPOS(1),YPOS(1):MOVE I:I=8
530 NEXT
540 RETURN
600 DEF MOVE(0)=SPRITE(10,0,1,1,0,0):POSITION 0,X,Y
610 PLAY"O5C5:O4E5:O1G5"
620 LOCATE 10,15:PRINT "GAME OVER"
630 MOVE 0,1,2
640 IF STRIG(0)<>1 THEN 620
650 GOTO 10
700 IF STRIG(0)=8 AND BOMT=0 THEN PLAY"O2C":BOMT=5:LOCATE 20,21:PRINT"        ":GOTO 720
710 GOTO 730
720 IF (XPOS(0)/20=XPOS(1)/20)AND(YPOS(0)/20=YPOS(1)/20) THEN DEF MOVE(1)=SPRITE(10,0,1,255,0,0):POSITION 1,SX,SY:MOVE 1:PLAY"O5C5:O4E5:O1G5":SUBH=10:SC=SC+10:LOCATE 15,21:PRINT SC
730 IF BOMT=1 THEN LOCATE 20,21:PRINT"FIRE OK!"
740 IF BOMT>0 THEN BOMT=BOMT-1
750 IF SUBH>0 THEN SUBH=SUBH-1
790 RETURN
800 DS=0
810 IF XPOS(K)<30 THEN DS=3
820 IF XPOS(K)>220 THEN DS=7
830 IF YPOS(K)<30 THEN DS=5
840 IF YPOS(K)>170 THEN DS=1
850 IF DS=0 THEN 890
860 IF K=1 THEN DEF MOVE(1)=SPRITE(7,DS,RND(3)+4,20,1,0):POSITION 1,SX,SY:MOVE 1:SF=DS:GOTO 890
870 CUT K:ERA K
890 RETURNs