Title: サッカーシュートゲーム (Soccer Shoot Game)
System: Family Basic
Author: 
Publication: 小学館入門百科シリーズ 191: きみにも作れる!! フアミリーコンピュータゲーム (Shogakukan Introductory Encyclopedia Series 191: You can make it too!! Family Computer Games)
Page Scans: 
Preserved By: ozidual
Recommended Emulator: VirtualNES

Article Translation

It's a kicking battle with Mario as the goalkeeper and Lady as the kicker. Aim for the goal with the spinner's curveball instead of the ball!

How to play and rules

The Lady will come running from the flag so kick the ball at the right time. If you score a goal, you'll get a fish. If you miss the goal or get caught by Mario, you'll get a score.
There are four chances to kick. The number of points scored is displayed on the scoreboard, you get one for each point scored. The Famicom decides whether or not the game is one and displays the result on the screen. If it's two-against-two, it will decided draws.
It's a game of timing when kicking the ball.

How to use the controller

To start the game, type in RUN and press RETURN. Press the B button and Lady will appear and start moving. Press the A button to kick. Press the START button to play again. Press the SELECT button to end the game.  The D-Pad is not used.


Code

90 CLEAR
100 GOSUB 1000
110 GOSUB 1200
120 GOSUB 2000
130 GOSUB 4000
140 IF A<5 THEN 110
150 PLAY"BAGFEDCBBBC"
160 GOSUB 1300:LOCATE 7,18
170 A$="キミノマケ"
180 IF AT=2 THEN A$="ヒキクケ"
190 IF AT>2 THEN A$="キミノカチ"
200 PRINT AT;"タイ";HA;"デ ";A$
210 S1=STRIG(0)
220 IF S1=1 THEN RUN
230 IF S1=2 THEN END
240 GOTO 210
1000 VIEW:'  ショキ
1010 SPRITE ON
1020 A=1:AT=0:HA=0
1030 CGSET 1,0
1040 PALETS 3,1,48,48,48
1050 FOR I=4 TO 7
1060 DEF SPRITE I,(0,1,0,0,0)="ケコサシ"
1070 NEXT
1080 DEF SPRITE 2,(3,1,0,0,0)="ュョッガ"
1090 DEF SPRITE 3,(0,1,0,0,0)=CHR$(0)+CHR$(1)+CHR$(2)+CHR$(3)
1100 RETURN
1200 DEF SPRITE 0,(2,1,1,1,0)=")(+*"
1210 DEF SPRITE 1,(2,1,1,1,0)="-,/."
1220 DEF MOVE (0)=SPRITE (1,3,2,32,1,2)
1230 POSITION 0,28,143
1300 LOCATE 22,3:PRINT AT
1320 LOCATE 22,7:PRINT HA
1340 RETURN
2000 'ケル
2010 S1=STRIG(0)
2020 IF S1<>4 THEN 2010
2030 SPRITE 2,66,143
2040 SPRITE 3,175,143
2050 MOVE 0:PAUSE 10
2060 S1=STRIG(0)
2070 IF S1=8 THEN 2300
2080 IF MOVE(0)=0 THEN 2400
2090 GOTO 2050
2300 'ケル 1
2310 BEEP:SPRITE 2
2320 L1=XPOS(0)
2330 IF L1>65 AND L1<67 THEN TA=2:H0=0:GOTO 2500
2340 IF L1>=63 AND L1<=69 THEN TA=1:H0=RND(3)-1:GOTO 2500
2350 IF L1>=60 AND L1<=70 THEN TA=1:H0=RND(5)-2:GOTO 2500
2400 ERA 0
2410 LX=XPOS(0)
2420 SPRITE 1,LX,143
2430 TA=3
2440 RETURN
2500 ERA 0
2510 SPRITE 0,L1,143
2520 DEF MOVE(1)=SPRITE (7,3,1,40,0,3)
2530 POSITION 1,66,143
2540 MOVE 1
2550 H=ABS(H0):E=0
2560 IF H=0 OR H=1 THEN E=1
2570 IF MOVE(1)<>0 THEN 2570
2580 ON TA GOSUB 2600,2700,2800
2590 PAUSE 100:RETURN
2600 'ケル 1-1
2610 KY=22
2620 IF H0=0 THEN KY=1
2630 IF H>=2 THEN KY=30
2640 DEF MOVE (1)=SPRITE (7,3,1,KY,E,3)
2650 POSITION 1,146,143
2660 MOVE 1
2670 RETURN
2700 'ケル 1-2
2710 DEF MOVE (1)=SPRITE (7,2,1,12,E,3)
2720 POSITION 1,146,143
2730 MOVE 1
2740 IF MOVE(1)<>0 THEN 2740
2750 DEF MOVE (1)=SPRITE (7,3,1,10,E,3)
2760 POSITION 1,170,120
2770 MOVE 1
2780 RETURN
2800 'ケル 1-3
2810 DEF MOVE (1)=SPRITE (7,2,1,22,E,3)
2820 POSITION 1,146,143
2830 MOVE 1
2840 RETURN
4000 ' ハンテイ
4010 IF MOVE(1)<>0 THEN 4010
4020 IF ABS(H0)=2 THEN 4200
4030 IF TA>=3 THEN 4200
4040 IF TA=1 AND H0=0 THEN 4200
4100 ' ハンテイ アタリ
4110 AT=AT+1
4120 PLAY "T5O3E3G#DGDG#DG#"
4130 SPRITE A+3,A*32-5,34
4150 GOTO 4300
4200 ' ハンテイ ハズレ
4210 HA=HA+1:PLAY"T5CCC"
4220 SPRITE A+3,A*32-5,66
4300 PAUSE 100:A=A+1:ERA1,2:RETURN