Title: と一め一人間 PART2 (One and Only Human PART 2)
System: Family Basic
Author: GORO一チン (Goro Ichin)
Publication: プログラムポシェット No. 11 (Program Pochette No. 11)
Page Scans: 
Preserved By: ozidual
Recommended Emulator: VirtualNES

Translated Article

"Tome Ichi Ningen", which appeared in Famimaga (Family Computer Magazine. Tomomi and I are also in cahrge of Ultech here), issue 9, has returned with an upgrade.

This time, you don't start out as an invisible man. The game involves moving yourself with Controller I and removing all the markes except for blocks. You stop when you release the controller. The marks are:

+ become invisible
¥ enemy disappears
! screen goes black
? screen returns to normal

This game is extremely difficult when you try it, and clearing the first level is quite difficult.


Variable List

X,Y - Your coordinates
TX,TY - Enemy coordinates
AX,AY - Change in your coordinates
XA,YA - Change in enemy coordinates
SC - Score
L - 
S - Read from the D-Pad
TM - Am I invisible?
MT - Is the enemy invisible?
SP - Release the controller and it will stop
DR - Number of marks


Program Description

10-30 - Intial settings
40-100 - Title
110 - Variable initialization
120-290 - Screen creation
300 - Your condition
310-430 - Your movement routine
440-490 - Enemy movement routine
500-540 - Game over
550-560 - Clear the screen


Code

10 CLS:SPRITEON:CGEN3:CGSET,0:PLAY"T1O3"
20 DEFSPRITE0,(0,0,0,0,0)=CHR$(207)
30 DEFSPRITE1,(1,0,0,0,0)=CHR$(219)
40 LOCATE 8,11PRINT"ト-メ-ニンゲン 2":COLOR 17,11,1
50 LOCATE -1,13PRINT"PUSH START":LOCATE10,15PRINT"BY GORO-チン"
60 FORI=0TO17:A$=A$+CHR$(193):NEXT
70 FORI=0TO15:B$=B$+"$":NEXT
80 PALETB 0,14,48,39,22
90 PALETB 1,14,RND(60),33,2
100 IFSTRIG(0)<>1THEN90
110 CLS:SC=0L=5
120 FORI=2TO19:LOCATE4,I:PRINTA$:NEXT:FORI=3TO18:LOCATE5,I:PRINTB$:NEXT:DR=256
130 FORI=0TO L
140 X=RND(16)+5Y=RND(16)+3:IFSCR$(X,Y)="$"DR=DR-1
150 LOCATEX,Y:PRINT"?"
160 GOSUB280:TX=XX:TY=YY:PRINTCHR$(193)
170 IF X=TX AND Y=TY THEN160
180 NEXT
190 SPRITE0,X*8+15,Y*8+24
200 SPRITE1,TX*8+15,TY*8+24
210 Q$="+":W$="￥":E$="!":F$="-"
220 FORI=0TO L
230 GOSUB280:PRINTQ$
240 GOSUB280:PRINTW$
250 GOSUB280:PRINTE$
260 GOSUB280:PRINTF$
270 NEXT:GOTO300
280 XX=RND(16)+5YY=RND(16)+3IFSCR$(XX,YY)=CHR$(193) GR=GR+1
290 LOCATEXX,YY:RETURN
300 AX=0AY=0SP=0TM=0MT=0PALETB 0,14,48,39,22
310 S=STICK(0):IF S=0 AND SP=1 THEN330
320 AX=(S=2)-(S=1)AY=(S=8)-(S=4)
330 X=X+AX:Y=Y+AY:IF TM=0SPRITE0,X*8+15,Y*8+24
340 IF X=TX AND Y=TY THEN500
350 SC$=SCR$(X,Y)
360 DR=DR-1IFSC$=" " DR=DR+1GOTO430
370 IFSC$=CHR$(193)THEN500
380 SC=SC+1LOCATEX,Y:PRINT" ":IFSC$="?" PLAY"C0"GOTO 300
390 IFSC$=Q$ SPRITE0:TM=1PLAY"D0"
400 IFSC$=W$ SPRITE1:MT=1PLAY"E0"
410 IFSC$=E$ PALETB 0,14,14,14,14PLAY"F0"
420 IFSC$=F$SP=1PLAY"A0"
430 IFDR=0THEN550
440 IFK<4THEN470
450 K=0IFRND(2)=1XA=0YA=SGN(Y-TY)GOTO470
460 XA=SGN(X-TX):YA=0:GOTO470
470 TX=TX+XA:TY=TY+YA:IF MT=0 THENSPRITE1,TX*8+15,TY*8+25
480 IF X=TX AND Y=TY THEN500
490 K=K+1GOTO310
500 PALETB 0,14,48,33,2:SPRITE0:SPRITE1,TX*8+16,TY*8+24
510 LOCATEX,Y:PRINTCHR$(215):PLAY"O0C4DEDC"
520 LOCATE2,21PRINT"YOUR SCORE IS";SC
530 IFSTRIG(0)<>2THEN530
540 RUN
550 PALETB 0,14,48,37,23
560 LOCATEX,Y:PRINTCHR$(199):PLAY"C3DEDC"L=L+5SC=SC+100GOTO120