Title: マリオとレディの相性うらない (Mario and Lady Compatibility Fortune Telling)
System: Family Basic
Author: 
Publication: 小学館入門百科シリーズ 191: きみにも作れる!! フアミリーコンピュータゲーム (Shogakukan Introductory Encyclopedia Series 191: You can make it too!! Family Computer Games)
Page Scans: 
Preserved By: ozidual
Recommended Emulator: VirtualNES

Keyboard only

Article Translation

The Famicom has a fortune telling system that uses biorhythms to predict your future, but the fortune telling I want to know more about is about my compatibility with that girl I've got a crush on.
As instructed by the Famicom, enter your zodiac sign in katakana (press the kana key to switch to kana mode), then enter the other person's zodiac.  The girl will walk towards the center of the heart in proportion to your compatibility. If you walk towards each other as if they were hearts, it will be the best box divination. If you stop in the middle, the Famicom will judge your relationship with each other in an exciting fortune telling.

How to use the keyboard

The names of the constellations are written in katakana as "OOZA". When you press the last key, the other person will ask for the name of their sign. It's important to write all the way down to "ZA". To write the characters for "Graphic Letters", press the GRPH key while pressing the key for that character. No controller is used.


Code

10 '
20 VIEW:X=0:DIM DX(1)
30 FOR I=0 TO 1
40 IF I=0 THEN S1$="キミ ノ "
50 IF I=1 THEN S1$="アイテ ノ "
60 S$=S1$+"セイザ ハ ?"
70 Y=3:GOSUB 1500
80 GOSUB 1000
90 Y=21:IF I=1 THEN X=15
100 GOSUB 2000:X=0
110 GOSUB 300:DX(I)=D
120 NEXT
130 GOSUB 500
140 MX=DD*12:SPRITE ON:CGSET1,0:GOSUB 600
150 IF DD=1 THEN S1$="モウスコシ ドリョクガ ヒツヨウ"
160 IF DD=2 THEN S1$="オトモダチ  ノ アイダガラ"
170 IF DD=3 THEN S1$="トテモ キノアウ アイダガラ"
180 IF DD=4 THEN S1$="コイビトドウシ ト イエソウ"
190 IF DD=5 THEN S1$="ネツレツ ナ コイビトドウシ"
200 S$="フタリ ハ "+S1$+" デス。"
210 Y=3:GOSUB 1500:GOSUB 1000
220 PAUSE
300 '
310 D$=MID$(DA$,2,1)
320 IF D$="ヒ" THEN D=0
330 IF D$="ウ" THEN D=1
340 IF D$="タ" THEN D=2
350 IF D$="ニ" THEN D=3
360 IF D$="シ" THEN D=4
370 IF D$="ト" THEN D=5
380 IF D$="ン" THEN D=6
390 IF D$="ソ" THEN D=7
400 IF D$="テ" THEN D=8
410 IF D$="キ" THEN D=9
420 IF D$="ス" THEN D=10
430 IF D$="オ" THEN D=11
440 RETURN
500 '
510 DZ=(12*DX(0))+DX(1):RESTORE
520 FOR I=0 TO DZ
530 READ DD
540 NEXT
550 RETURN
600 '
610 DEF MOVE(1)=SPRITE(0,3,5,MX,0)
620 DEF MOVE(2)=SPRITE(1,7,5,MX,0)
630 POSITION 1,0,120
640 POSITION 2,248,120
650 MOVE 1,2
660 IF M1<>XPOS(1) THEN BEEP:M1=XPOS(1)
670 IF MOVE(1)=-1 GOTO 660
680 RETURN
1000 '
1010 LOCATE X,Y
1020 S0=LEN(S$)
1030 FOR J=1 TO S0
1040 SD$=MID$(S$,J,1):PRINT SD$
1050 IF SD$<>" " THEN BEEP
1060 PAUSE 10
1070 NEXT
1080 RETURN
1500 '
1510 LOCATE X,Y
1520 PRINT"                            "
1530 RETURN
2000 '
2010 LOCATE X,Y:DA$=""
2020 A$="":A$=INKEY$:IF A$="" GOTO 2020
2030 D0=ASC(A$)
2040 IF D0=8 THEN 2070
2050 IF D0=29 THEN 2070
2060 GOTO 2080
2070 GOSUB 1500:BEEP:GOTO 2000
2080 DA$=DA$+A$:PRINT A$;:BEEP
2090 IF A$<>"ザ" THEN 2020
2100 RETURN
9000 DATA 5,3,4,1,5,3,4,2,5,1,4,2,3,5,2,4,1,5,2,4,3,5,1,4,4,2,5,3,4,1,5,3,4,2,5,1,1,4,3,5,2,4,1,5,2,4,3,5,5,1,4,2,5,3,4,1,5,3,4,2,3,5,1,4,3,5,2,4,1,5,2,4,4,2,5,1,4,2,5,3,4,1,5,3,2,4,3,5,1,4,3,5,2,4,1,5,5,3,4,2,5,1,4,2,5,3,4,1,1,5,2,4,3,5,1,5,3,4,2,4,4
9010 DATA 1,5,3,4,2,5,1,4,2,5,3,2,4,1,5,2,4,3,5,1,4,3,5