10 SPRITEON:CGSET1,0
20 PLAY"M1Y1V15:M1Y1V15"
30 DEFMOVE(0)=SPRITE(0,3,1,10,0,0):DEFMOVE(1)=SPRITE(0,7,1,10,0,0):DEFMOVE(2)=SPRITE(0,3,1,10,0,1):DEFMOVE(3)=SPRITE(0,7,1,10,0,1)
40 DEFMOVE(6)=SPRITE(10,1,1,10,0,0)
50 K=0:V1=110:S=0:F=2:R=1:W=1
60 GOTO480
70 VIEW
80 DEFMOVE(4)=SPRITE(M,3,1,10,0,0):DEFMOVE(5)=SPRITE(M,7,1,10,0,0)
90 VIEW:LOCATE2,5:PRINTV1:LOCATE23,5:PRINTV2:LOCATE21,1:PRINTA$:LOCATE0,21:PRINT"GET        ITEM":LOCATE2,22:PRINTB$:LOCATE12,7:PRINTF
100 LOCATE12,4:PRINTW
110 LOCATE16,21:PRINT"A.D QUALIFY";:LOCATE17,22:PRINT"ATTACK"A;:LOCATE17,23:PRINT"DAMEGE"D;
120 POSITIONS,100,160:POSITION5,190,160:SS=S:X=5:XX=5
130 LOCATE15,0:PRINTR
140 REM MA
150 IFSTRIG(0)=1OR STRIG(0)=4THENGOSUB850
160 IFMOVE(S)=-1THEN230
170 IFSTICK(0)<>1AND STICK(0)<>2THEN230
180 IFSTICK(0)=1THENS=0
190 IFSTICK(0)=2THENS=1
200 IFSTRIG(0)=8THENB=1:S=S+2:GOTO220
210 B=0
220 POSITIONS,XPOS(SS),YPOS(SS):ERASS:MOVES:SS=S
230 IFMOVE(X)=-1THEN290
240 IF(RND(3)+1)=1THEN270
250 IFXPOS(SS)>XPOS(XX)THENX=4:GOTO280
260 X=5:GOTO280
270 X=RND(2)+4
280 POSITION X,XPOS(XX),YPOS(XX):ERAXX:MOVEX:XX=X
290 IFB=1THENT=T+1:IFT>170THENV1=V1-5:T=0:LOCATE2,5:PRINTV1" ":IFV1<0THEN960
300 Q=Q+1:IFQ=8THENPLAY"T1O0C1":Q=0
310 IFMOVE(7)=0THENGOSUB900
320 IFFI=1THEN910
330 IFABS(XPOS(SS)-XPOS(XX))<8THEN360
340 GOTO150
350 REM AD
360 I=RND(2)
370 IFB=1ANDI=1THENV1=V1-D:V2=V2-A
380 IFB=1ANDI=0THENV2=V2-A
390 IFB=0ANDI=1THENV1=V1-(D+D/2)
400 IFB=0ANDI=0THENV1=V1-D/2:V2=V2-5
410 LOCATE2,5:PRINTV1" ":LOCATE23,5:PRINTV2" "
420 PLAY"T1O1F0ECO0BGEC:T1E0DCO0AFED"
430IFV1<0THEN960
440 IFV2<0THEN1040
450 IFV1<31ANDK=0THENGOSUB1230
460 GOTO150
470 REM SH
480 CLS:LOCATE7,0:PRINT"KAGEMON BUSTER"
490 PLAY"T2O3C5:T2O2#G5:T2O2#D5":PLAY"O2#A3#A#A:G3GG:D3DD":PLAY"#G5G#FG9:#D5D#CD9:C5O1B#A#A9
500 LOCATE9,5:PRINT"PUSH START"
510 IFSTRIG(0)<>1THEN510
520 K=0:V1=V1+40:CLS:LOCATE6,0:PRINT"MONSETR   DECIDE"
530 LOCATE9,5:PRINT"PUSH START"
540 IFSTRIG(0)<>1THEN540
550 FORI=0TO RND(10)+10:PLAY"T1O3C2R1":NEXT
560 IFR MOD 5=0THEN580
570 ON RND(4)+1 GOTO 590,600,610,620
580 M=13:A$="KEMEGON":V2=RND(150)+150:D=RND(15)+15:GOTO630
590 M=14:A$="F.CRAB":V2=RND(100)+40:D=RND(5)+15:GOTO630
600 M=4:A$="PENTER":V2=RND(130)+30:D=RND(10)+8:GOTO630
610 M=2:A$="F.FLY":V2=RND(80)+70:D=RND(10)+5:GOTO630
620 M=5:A$="FIREN":V2=RND(100)+80:D=RND(5)+12
630 V2=V2+R*5:D=D+R/3:PLAY"T2O3F5D3E5:T2O3D3O2AFA5":PLAY"A8:A8"
640 LOCATE3,18:PRINT"YOUR ENEMY IS "A$"!":PAUSE200
650 CLS:LOCATE 7,0:PRINT"ITEM    DECIDE":LOCATE9,5:PRINT"PUSH START"
660 IF ASC(INKEY$)=64+M THENF=F+5:PLAY"T1E3C":GOTO680
670 IFSTRIG(0)<>1THEN660
680 FORI=0TO RND(10)+10:PLAY"T1O3C2R1":NEXT
690 A=10:ON RND(10)+1 GOTO 700,710,720,730,740,750,760,770,780,790
700 B$="SWAP PORTION":W=W+1:GOTO800
710 B$="DEATH PORTION":V2=V2+RND(70):GOTO800
720 B$="FIRE BALL":F=F+1:GOTO800
730 B$="RED PORTION":V1=V1-RND(V1):GOTO800
740 B$="SHIELD":D=D-(RND(3)+5):GOTO800
750 B$="NO ITEM":GOTO800
760 B$="BLUE PORTION":V1=V1+(RND(30)+20):GOTO800
770 B$="SHAM SWORD":A=A-(RND(4)+5):GOTO800
780 B$="SUPER SWORD":A=A+(RND(7)+3):GOTO800
790 B$="RED RING":D=0
800 PLAY"T3:T3:T3":PLAY"O3C3C1C:O2G3G1G:O2#D3#D1#D":PLAY"O2#A2O3CDE6:G2GAB6:D2#DFG6"
810 LOCATE7,14:PRINT"YOU GET ITEM IS ":LOCATE9,16:PRINTB$
820 PAUSE 300
830 GOTO70
840 REM IT
850 IFW=0THEN870
860 IFSTRIG(0)=1PLAY"T1O2C0DEFGABO3CDEFGA":SWAPV1,V2:LOCATE2,5:PRINTV1"  ":LOCATE23,5:PRINTV2"  ":W=W-1:LOCATE12,4:PRINTW" ":RETURN
870 IFF=0THEN RETURN
880 DEFMOVE(7)=SPRITE(12,VCT(S),1,60,0,0):POSITION7,XPOS(S),YPOS(S):PLAY"T1O5B0GECO4AGDC9"
890 F=F-1:FI=1:MOVE7:LOCATE12,7:PRINTF" ":RETURN
900 ERA7:FI=0:RETURN
910 IFABS(XPOS(7)-XPOS(XX))<8THEN930
920 GOTO340
930 FI=0:V2=V2-(RND(40)+40):LOCATE23,5:PRINTV2" "
940 GOTO440
950 REM GO
960 LOCATE2,5:PRINT0" ":POSITION 6,XPOS(SS),YPOS(SS):MOVE6:ERASS:PLAY"T1O1#C5C8:T1O1#C5#C8:T1O1C5C8":PAUSE15
970 PLAY"O3T3G3FDO2B:O2T3G3FDO1B":PLAY"GFDO1B:GFDO0B:T3"
980 LOCATE6,11:PRINT"G A M E  O V E R"
990 PLAY"D6C3C7:O1#G6G3G7:O1F6#D3#D6"
1000 LOCATE9,13:PRINT"TRY AGAIN":LOCATE8,14:PRINT"PUSH  START"
1010 IF STRIG(0)<>1THEN1010
1020 ERAXX,6,7:GOTO50
1030 REM RC
1040 LOCATE23,5:PRINT0" ":POSITION6,XPOS(XX),YPOS(XX):MOVE6:ERAXX:PLAY"O0T2E1DC7":LOCATE8,11:PRINT"ROOM  CLEAR"
1050 PLAY"T2O3"
1060 PLAY"E3F#FG5E3F5D3:T2O1R5R3G5R3#G5":PLAY"E5C3D5O2B3:A5R3B5":PLAY"O3C6O4C5O3C7:O2C7R3C7"
1070 PAUSE200:ERASS,6,7
1080 IFR MOD5=0THENGOSUB1120
1090 CLS:R=R+1:LOCATE9,11:PRINT"NEXT  ROOM"
1100 PAUSE150:GOTO520
1110 REM PR
1120 DEFMOVE(7)=SPRITE(1,7,1,16,0,1)
1130 PLAY"O2T1C4DEFGAB9:O2T1R3D4EFGAB9"
1140 POSITION0,80,160:POSITION7,210,160
1150 MOVE0,7:PAUSE100
1160 FORI=0TO11:MOVE7:PLAY"T1O2C0F":NEXT
1170 FORI=0TO7:LOCATE 0,I:PRINT"                            ";:NEXT
1180 PLAY"T2O3G5D3DG7:T2O3D5O2B3BO3D7":PLAY"O2B3BO3DCO2AAO3C:D3DGFCCF":PLAY"AGFAB9R5B9:O3EDCF#G9R5#G9"
1190 PLAY"O3G5D3DG7:O3D5O2B3BO3D7":PLAY"O2B3BO3DCO2AAO3C:D3DGFCCF":PLAY"AGFAB9R5B9:O3EDCF#G9R5#G9"
1200 LOCATE6,0:PRINT"CONGRATULATIONS"
1210 LOCATE0,2:PRINT"BUT SHE AGAIN CAPTURED THEY":LOCATE4,4:PRINT"YOU AGAIN GO TO TRIP":LOCATE6,6:PRINT"TO SAVE PRINCESS"
1220 PAUSE400:ERA0,7:RETURN
1230 FORI=0TO5:FILTER7:PLAY"T2O2G2:T2O1A2":FILTER0:PLAY"C2:D2":NEXT:K=1:RETURN
