Title: ジャンぺンゲ一ム (Jump Game)
System: Family Basic
Author: 
Publication: 小学館入門百科シリーズ 191: きみにも作れる!! フアミリーコンピュータゲーム (Shogakukan Introductory Encyclopedia Series 191: You can make it too!! Family Computer Games)
Page Scans: 
Preserved By: ozidual
Recommended Emulator: VirtualNES

Article Translation

Move Penpen up and down to defeat and eliminate the characters launched by the enemy. The strength of the turtle, crab, and crow is as shown in the diagram below. A win or a tie is worth 50 points. If you reach the goal in the enemy's territory, you get 100 points, and you can subtract 1 point from the enemy's 20 points. The fly can defeat any character, but even if it wins, it will only get 10 points.
The game ends when either player's 20 points reach zero (when the opponent scores 20 times). The player with the highest score wins by multiplying the remaining points by 100 and adding it to their score. A split-second decision can determine victory or defeat. Do your best.


Crab clicks Turtle clicks Crow clicks Crab
Crab makes Crow makes Turtle makes Crab
Flies have the ability to beat any character but his score is low

How to use the controller

Type in RUN and hit RETURN to start. Press START to restart the game. Presse SELECT to end the game. The color changes when you press A. Press B to fire each character you have drawn. Use the D-Pad to move up and down.


Code:

99 '*メイン
100 DIM O(7):VIEW:CGEN 2
110 SPRITE ON:CGSET 1,2:PLAY"T1M0V9"
120 RESTORE 180
130 FOR I=0 TO 3
140 READ K
150 DEF MOVE(I*2)=SPRITE(K,3,2,255,0,I)
160 DEF MOVE(I*2+1)=SPRITE(K,7,2,255,0,I)
170 NEXT
180 DATA 15,2,14,13
190 C1=0:C2=0:Y1=120:Y2=120:L1=20:L2=20
200 GOSUB 6000:GOSUB 7000:GOSUB 8000:GOSUB 9000
210 GOSUB 2000:GOSUB 4000:GOSUB 5000:GOTO 210
220 LOCATE 9,9:PRINT"ゲ-ム オ-バ-"
230 I=STRIG(0)
240 IF I=1 THEN RUN
250 IF I=2 THEN END
260 GOTO 230
999 '*ドウサ1
1000 ST=STICK(0)
1010 T=STRIG(0)
1020 IF ST=0 THEN 1060
1030 IF ST=4 THEN Y1=Y1+32:IF Y1>152 THEN Y1=56
1040 IF ST=8 THEN Y1=Y1-32:IF Y1<56 THEN Y1=152
1050 GOSUB 8500
1060 IF T=0 THEN 1110
1070 IF T=8 THEN C1=C1+1:IF C1>3 THEN C1=0
1080 GOSUB 8000
1090 W=C1*2
1100 IF T=4 AND MOVE(W)=0 THEN POSITION W,48,Y1:MOVE W:O(W)=1
1109 '*ドウサ2
1110 ST=RND(9)
1120 T=RND(9)
1130 IF ST=0 THEN 1170
1140 IF ST=4 THEN Y2=Y2+32:IF Y2>152 THEN Y2=56
1150 IF ST=8 THEN Y2=Y2-32:IF Y2<56 THEN Y2=152
1160 GOSUB 9500
1170 IF T=0 THEN RETURN
1180 IF T=8 THEN C2=C2+1:IF C2>3 THEN C2=0
1190 GOSUB 9000
1200 W=C2*2+1
1210 IF T=4 AND MOVE(W)=0 THEN POSITION W,192,Y2:MOVE W:O(W)=1
1220 RETURN
1999 'ゲキトツ
2000 FOR I=0 TO 6 STEP 2
2010 GOSUB 1000
2020 IF O(I)=0 THEN 2060
2030 FOR J=1 TO 7 STEP 2
2040 IF O(J)=1 AND YPOS(I)=YPOS(J) AND ABS(XPOS(I)-XPOS(J))<24 THEN GOSUB 3000
2050 NEXT
2060 NEXT
2070 RETURN
2999 '*カチマケ
3000 IF I=2 THEN ERA J:O(J)=0:S1=S1+10:GOSUB 6500
3010 IF J=3 THEN ERA I:O(I)=0:S2=S2+10:GOSUB 7500
3020 IF I=2 OR J=3 THEN RETURN
3030 IF I=0 AND J=7 THEN 3080
3040 IF I=4 AND J=1 THEN 3080
3050 IF I=6 AND J=5 THEN 3080
3060 ERA I:O(I)=0:S2=S2+50:GOSUB 7500
3070 IF I<>J-1 THEN RETURN
3080 ERA J:O(J)=0:S1=S1+50:GOSUB 6500
3090 RETURN
3999 '*ゴ-ル1
4000 FOR I=0 TO 6 STEP 2
4010 IF O(I)=1 AND XPOS(I)>192 THEN ERA I:O(I)=0:S1=S1+100:L2=L2-1:GOSUB 6000:IF L2<1 THEN 220
4020 NEXT
4030 RETURN
4999 '*ゴ-ル2
5000 FOR I=1 TO 7 STEP 2
5010 IF O(I)=1 AND XPOS(I)<48 THEN ERA I:O(I)=0:S2=S2+100:L1=L1-1:GOSUB 7000:IF L1<1 THEN 220
5020 NEXT
5030 RETURN
5999 '*スコア1
6000 LOCATE 21,1:PRINT L2;" "
6500 LOCATE 6,1:PRINT S1;" ":PLAY"O4E0B1":RETURN
6999 '*スコア2
7000 LOCATE 2,1:PRINT L1;" "
7500 LOCATE 15,1:PRINT S2;" ":PLAY"O3E0B1":RETURN
7999 '*ペンペン1
8000 DEF SPRITE 0,(C1,1,0,1,0)="イアエウ"
8500 SPRITE 0,32,Y1:RETURN
8999 '*ペンペン2
9000 DEF SPRITE 1,(C2,1,0,0,0)="アイウエ"
9500 SPRITE 1,208,Y2:RETURN
