1 CLS:CGSET1,0:SPRITEON:PLAY"A0"
2 D=167:MT=0:LT=0:PO=5
10 SX=180:LX=60
20 SY=167:LY=167:BX=D:BY=159:YY=16:XX=0:VIEW:GOSUB 40
30 LOCATE1,3:PRINTLT
31 LOCATE21,3:PRINTMT
32 IFLT=PO THENK$=" マリオ":GOTO500
33 IFMT=PO THENK$="ルイ-ジ":GOTO500
34 IFLT=PO-1ANDMT=PO-1THENPO=PO+1:GOSUB1000
35 GOSUB 62:GOTO66
40 DEFSPRITE1,(1,1,0,0,0)=CHR$(0)+CHR$(1)+CHR$(2)+CHR$(3):RETURN
50 DEFSPRITE1,(1,1,0,0,0)=CHR$(4)+CHR$(5)+CHR$(6)+CHR$(7):RETURN
60 DEFSPRITE1,(1,1,0,0,0)=CHR$(8)+CHR$(9)+CHR$(10)+CHR$(11):RETURN
62 DEFSPRITE2,(0,1,0,1,0)=CHR$(1)+CHR$(0)+CHR$(3)+CHR$(2):RETURN
63 DEFSPRITE2,(0,1,0,1,0)=CHR$(5)+CHR$(4)+CHR$(7)+CHR$(6):RETURN
64 DEFSPRITE2,(0,1,0,1,0)=CHR$(9)+CHR$(8)+CHR$(11)+CHR$(10):RETURN
66 DEFSPRITE0,(3,0,0,0,0)=CHR$(223)
70 I=STICK(1):M=M-(I=1)+(I=2):SX=SX+(I=2 AND SX>134)*4-(I=1 AND SX<220)*4
75 H=STICK(0):L=L-(H=1)+(H=2):LX=LX+(H=2ANDLX>16)*4-(H=1ANDLX<105)*4
76 YY=YY-1:BY=BY-YY:BX=BX+XX
77 SPRITE0,BX,BY
78 IFBY>158THENGOSUB 120
79 IFBX<132ANDBX>129ANDXX<0 ANDBY>116THENXX=ABS(XX)
80 IFBX>116ANDBX<128ANDXX>0 ANDBY>116THENXX=VAL("-"+STR$(XX))
81 IFM<1THENM=3
90 IFM>3THENM=1
91 IFL<1THENL=3
92 IFL>3THENL=1
93 S=STRIG(0):IFS=8ANDS1<>8THENLY=164:D=2:DY=16
94 IFS=4ANDS1<>4THENLY=164:D=4:DY=13
95 SS=STRIG(1):IFSS=8ANDG<>8THENSY=164:D1=-2:DY1=16
96 IFSS=4ANDG<>4THENSY=164:D1=-4:DY1=13
100 IFI=1ORI=2THENON M GOSUB40,50,60
101 IFH=1ORH=2THENON L GOSUB62,63,64
102 SY=SY+1:IFSY>167THENSY=167
103 LY=LY+1:IFLY>167THENLY=167
104 S1=S:G=SS
105 SPRITE2,LX,LY
110 SPRITE1,SX,SY:GOTO70
120 IFBX>128THEN130
121 IFLY<167THENIFBX+3>LX+5ANDBX+3<LX+19THENYY=DY:XX=D:PLAY"O3C0":RETURN
125 BX=BX+XX:SPRITE0,BX,BY+17:MT=MT+1:D=167:PLAY"T7O1CDEFCCC":GOTO10
130 IFSY<167THENIFBX+3<SX+11ANDBX+3>SX-3THENYY=DY1:XX=D1:PLAY"O3C0":RETURN
135 BX=BX+XX:SPRITE0,BX,BY+17:LT=LT+1:D=80:PLAY"T7O1CDEFCCC":GOTO10
500 LOCATE10,8:PRINTK$+" ノ カチ":LOCATE6,10:PRINT"PUSH START KEY!!!"
510 IFSTRIG(0)=1THENRUN
520 GOTO510
1000 FOR I=0TO2
1010 LOCATE12,2:PRINT"ジュ-ス"
1020 PLAY"T7O3E"
1030 LOCATE12,2:PRINT"    "
1035 FORW=0TO50:NEXT
1040 NEXT:RETURN