Title: 高射砲ゲーム (Flak Game)
System: Family Basic
Author: 
Publication: 小学館入門百科シリーズ 191: きみにも作れる!! フアミリーコンピュータゲーム (Shogakukan Introductory Encyclopedia Series 191: You can make it too!! Family Computer Games)
Page Scans: 
Preserved By: ozidual
Recommended Emulator: VirtualNES

Article Translation

The Earth has been attacked by a flying saucer from the planet Spinner which came from far away space. Defend the Earth with anti-aircraft guns built in mountainous areas!
The Spinner-type flying saucers and the KATANA were flying at extremely high altitudes, with the Nitpicker and Fighter fly Oka Zakus guarding them from below.
There are 10 Achilles bullets. The Achilles bullets have a boomerang effect, so they come back when they hit an enemy and can be used again for attacking. When the number of Achilles reaches 0, the game is over.
The higher the enemy's altitude, the higher the score:

300 points = Spinner
100 points = Knit Picker
50 points = Fighter Fly

The enemy sometimes changes its flight speed, so you need to aim carefully before completing the attack.


How to use the controller

To start the game, type in RUN and hit RETURN. Use the joystick to move anti-aircraft gun left and right, and use the A button to fire Achilles. If Achilles is flying, you cannot fire more Achilles. To restart the game, press the START button.


Corrections

Page 133:

11-24 M60


Code

10 VIEW:SPRITE ON:CGSET 0,1
20 DIM C(3,3):AC=10
25 DATA 7,15,2,3,7,3,20,50,80
30 FOR I=1 TO 3:FOR J=1 TO 3:READ C(I,J):NEXT:NEXT
40 REM ERROR IN BOOK, MOVED TO 25
50 DEF SPRITE 0,(0,1,0,0,0)="ピプペポ"
60 DEF MOVE(4)=SPRITE(3,1,2,100,0,0)
70 DEF MOVE(5)=SPRITE(10,0,7,10,0,0)
80 DEF SPRITE 6,(0,1,0,0,0)="TUVW"
90 GOTO 1500
100 FOR K=1 TO 3:GOSUB 500:NEXT
110 GOTO 1000
120 GOTO 1100
130 IF AC<1 GOTO 300
140 GOTO 110
150 IF K=1 THEN SC=SC+300
160 IF K=2 THEN SC=SC+100
170 IF K=3 THEN SC=SC+50
180 AC=AC+1
190 LOCATE 9,23:PRINT SC;
200 LOCATE 3,23:PRINT"   ";:LOCATE 3,23:PRINT AC;
210 GOTO 130
300 '
310 LOCATE 8,10:PRINT"GAME OVER"
320 IF SC>HC THEN HC=SC:LOCATE 19,23:PRINT HC;
330 T=STRIG(0):IF T<>1 GOTO 330
340 LOCATE 8,10:PRINT"           "
350 AC=10:SC=0
360 GOTO 90
500 '
510 D=RND(5)+1
520 DEF MOVE(K)=SPRITE(C(1,K),C(2,K),D,125,0,0)
530 POSITION K,XP,C(3,K)
540 MOVE K
550 RETURN
1000 '
1010 S=STICK(0)
1020 IF S=1 THEN X0=X0+1
1030 IF S=2 THEN X0=X0-1
1040 IF X0<0 THEN X0=0
1050 IF X0>240 THEN X0=240
1060 IF XZ=X0 GOTO 120
1070 SPRITE 0:SPRITE 0,X0,180:XZ=X0
1080 GOTO 120
1100 T=STRIG(0)
1110 IF MOVE(5)=0 THEN ERA 5
1120 IF MOVE(1)=0 THEN K=1:GOSUB 500
1130 IF MOVE(2)=0 THEN K=2:GOSUB 500
1140 IF MOVE(3)=0 THEN K=3:GOSUB 500
1150 IF T=8 GOTO 1170
1160 GOTO 130
1170 AC=AC-1:LOCATE3,23:PRINT"   ";:LOCATE 3,23:PRINT AC;
1200 '
1210 POSITION 4,X0,170:MOVE 4
1220 CUT 1,2,3,4
1230 Y=YPOS(1)-YPOS(4):IF Y<9 AND Y>-9 THEN K=1:GOTO 1300
1240 Y=YPOS(2)-YPOS(4):IF Y<9 AND Y>-9 THEN K=2:GOTO 1300
1250 Y=YPOS(3)-YPOS(4):IF Y<9 AND Y>-9 THEN K=3:GOTO 1300
1280 IF YPOS(4)<20 THEN ERA 4:MOVE 1,2,3:GOTO 130
1290 MOVE 1,2,3,4:BEEP:GOTO 1220
1300 X=XPOS(K)-XPOS(4)
1310 IF X<9 AND X>-9 GOTO 1330
1320 GOTO 1280
1330 POSITION 5,X0,YPOS(4):ERA 4,K:MOVE 5
1340 PLAY"T1O4EDC"
1350 GOSUB 500:MOVE 1,2,3:GOTO 150
1500 '
1510 SPRITE 6,10,200
1520 LOCATE 9,22:PRINT"SCORE     HI-SCORE";
1530 LOCATE 3,23:PRINT"10     0        ";HC;
1540 GOTO 100