Title: Famicom Daisakusen Family Basic Hop Game
System: Family Basic
Author: 
Publication: ファミコン大作戦 ファミリーベーシック ホップ (Famicom Daisakusen Family Basic Hop)
Page Scans: 
Preserved By: ozidual
Recommended Emulator: VirtualNES

Typer's Notes

You move left/right with the D-Pad and shoot with the A Button. Your opponent (CPU) is at the top of the screen moving down toward you at the bottom of the screen. The object of the game is to destroy the enemy ship repeatedly to gain as many points as possible before you run out of lives. You can each only shoot one shot at a time. Each time you destroy an enemy ship, you get 10 points. You only have 3 lives. If the enemy reaches the bottom of the screen, they just start over at the top of the screen again.

Famicom Daisakusen Family Basic Hop is the 1st in a series of 3 books that teach you Family Basic. The game here is the culmination of this first book.


Code

10 CLS
20 SPRITE ON
30 DEF SPRITE 0,(0,1,0,0,0)=CHR$(172)+CHR$(173)+CHR$(174)+CHR$(175)
40 DEF SPRITE 1,(0,0,0,0,0)=CHR$(212)
50 DEF SPRITE 2,(0,1,0,0,1)=CHR$(162)+CHR$(163)+CHR$(160)+CHR$(161)
60 DEF SPRITE 3,(0,0,0,0,0)=CHR$(212)
70 DEF SPRITE 4,(0,1,0,0,0)=CHR$(180)+CHR$(181)+CHR$(182)+CHR$(183)
90 SC=0:SH=3
100 AX=120:BX=120:BY=5
200 IF STICK(0)=1 THEN AX=AX+1
210 IF STICK(0)=2 THEN AX=AX-1
220 IF AX<0 THEN AX=0
230 IF AX>240 THEN AX=240
240 BY=BY+RND(2):BX=BX+RND(-1)-4
250 IF BX>240 THEN BX=240
260 IF BX<0 THEN BX=0
270 IF BY>220 THEN BY=5
300 IF FA=1 THEN CY=CY-4
310 IF FB=1 THEN DY=DY+4
320 IF FA=1 AND CY<5 THEN FA=0:SPRITE 1
330 IF FB=1 AND DY>220 THEN FB=0:SPRITE 3
350 IF FA=0 AND STRIG(0)=8 THEN FA=1:CX=AX+4:CY=212
360 IF FB=0 AND RND(6)=1 THEN FB=1:DX=BX+4:DY=BY+16
400 IF FA=1 AND CX+3>BX AND CX+3<BX+15 AND CY+2>BY AND CY+2<BY+15 THEN 1000
410 IF FB=1 AND DX+3>AX AND DX+3<AX+15 AND DY+5>220 AND DY+5<235 THEN 1500
500 SPRITE 0,AX,220
510 IF FA=1 THEN SPRITE 1,CX,CY
520 SPRITE 2,BX,BY
530 IF FB=1 THEN SPRITE 3,DX,DY
700 GOTO 200
1000 FA=0:SPRITE 1:SPRITE 2
1010 SPRITE 4,BX,BY
1020 SC=SC+10
1100 GOTO 2000
1500 FB=0:SPRITE 3:SPRITE 0
1510 SPRITE 4,AX,220
1520 SH=SH-1
2000 LOCATE 10,5:PRINT "SCORE =";SC
2010 IF SH=0 THEN 3000
2020 LOCATE 10,8:PRINT "ノコリ =";SH
2100 BEEP
2110 FOR I=0 TO 1500:NEXT
2120 BEEP:SPRITE 4
2200 CLS:GOTO 100
3000 LOCATE 10,8:PRINT "GAME OVER !"
3100 END