Title: ダンジョン＆マリオ (Dungeon & Mario)
System: Family Basic
Author: 
Publication: ファミリーコンピュータゲーム攻略㊙︎テクニック (Family Computer Game Strategy Secret Techniques)
Page Scans: 
Preserved By: ozidual
Recommended Emulator: VirtualNES

Article Translation

Mario is Lost in a European Dungeon!

"Dungeon & Mario" is a game in whic your favorite Famicom game character, Mario, plays a major role. It is packed with role-playing game elements that have never been seen in Famicom games before, so it is a very fresh game that you will enjoy to the fullest.

First, let me give you a brief introduction to the story behind this "Dungeon & Mario" game.

One day, Mario traveled to Europe. You might think he was rich, but he wasn't. He actually won a quiz show on TC, and that's how he got there. The quiz questions were easy for me, because I'm smart. Ha ha ha.

I can laugh about it now, but the truth is it was no laughing matter. Strong monsters kept appearing one after the other, and I felt like I was dying. I had no idea that such a scary place existed in the world.

I'll tell you what it was like. Yes, it was when I went to see a castle in a remote part of England. Apparently, the castle was built during the time of a master crossbowman named William Tell, and it wasn't on any tourist route. To be honest, I don't really know why I went to such a place. It just happened naturally. It was as if I was being controlled by something.

The incident happened the moment he entered the castle. As soon as he stepped inside, a hole appeared in the ground and he fell in. When he came to, he found himself in a dark, dungeon-like place. Suddenly, he noticed a door right in front of him. In any TV drama or movie, if there is a door at a time like this, the main character usually opens it and goes inside. And of course that's what he did. By the way, on the door it said Page 1...

Mario Must Fight in 11 Small Rooms

Now, there are a total of 11 rooms that Mario must go through. In each room, there are monsters waiting for Mario such as Penpen, Shell Creeper, and Side stepper, who are usually friends but act as enemy monsters in this Dungeon & Mario game. However, there are more than just monsters. There are also apples that will give you power (increase your hit points) when you pick them up. In other words, you just need to pick up these apples and fight the monsters.
When fighting, aim for the monster when it is stationary, stand on top of it and press the A button. This will hit the monster. The trick seems to be to drive the monster into a cornerof the wall before fighting it. As you defeat enemies, Mario's strength will gradually increase. The higher this number, the stronger he is. Defeat lots of enemy monsters and make Mario stronger.
Now that you understand ho to play Dungeon & Mario, I'll introduce you to the enemy monsters hiding in the small rooms you have to pass through.

Level 1: Four Penpen the penguins appear. The character with the white faceis an enemy here, defeat him quickly
Level 2: It's shellcreeper the turtle. It may not seem scary, but it's actually pretty tough.
Level 3: Nita Nita approaches with a grin on his face. Let's give him a pat and tell him not to laugh too much.
Level 4: A flying Achilles appears. Don't let him poke you with his beak.
Level 5: These are Fighter Flies. They're very noisy buzzing creatures.
Level 6: A crab called Sidestepper. Watch out for the claws.
Level 7: The Spinner appears. He approaches while spinning around. He is a windmill ghost.
Level 8: Fireball is a ball of fire. It tries to burn you to death with heat.
Level 9: A bird called a Knit Picker attacks. This one, as you'd expect, flies through the air.
Level 10: A lady, a girl who is good friends with Mario. Lady, why are you here?
Level 11: Ahhhhh. What the hell. The Kuta characters here are a secret. Wait until you get there, I promise you will be surprised.

In this way, if Mario clears all 11 small rooms, he wins. Can your Mario get through these 11 difficult challenges?
In addition, there are four enemy monsters in each of the 11 small rooms. If you defeat two of them, you can basically leave through the door. Of course, it doesn't matter if you defeat them all. For example, if you're about to run out of hit points after defeating two of them, you can escape through the door and pick up the apple in the next room.
This is a type of game never before seen on a Famicom so let's have as much fun as we can.


Code

5 PO=30:HI=100:FR=1
10 DIM TP(4),TC(4),TX(4),TY(4),K(4)
20 CLS:VIEW:X=3:Y=10:SPRITE OFF:TK=4
30 IF FR=12 THEN LOCATE 5,10:PRINT "YOU ARE WIN!!":END
40 READ CA:FOR I=1 TO 4:TX(I)=23:TY(I)=10:TC(I)=0:TP(I)=RND(20)+2*FR:K(I)=RND(4):NEXT
50 CGSET 1,0:GOSUB 500:SPRITE ON:GOSUB 200
60 S=0:IF MOVE(0)=0 THEN S=STICK(0):GOTO 70
65 GOTO 140
70 CX=0:CY=0:ON S+1 GOTO 140,80,90,140,100,140,140,140,110
80 N=3:CX= 2:GOTO 200
90 F=8:N=7:CX=-2:GOTO 200
100 F=0:N=5:CY= 2:GOTO 200
110 F=2:N=1:CY=-2:GOTO 200
140 GOSUB 600:LOCATE 5,21:PRINT HI,"  ",PO,"  "
160 IF HI<0 THEN LOCATE 5,10:PRINT "YOU ARE DEAD":END
190 GOTO 60
200 S$=SCR$(X+CX,Y+CY)
210 IF S$=" " THEN 240
220 IF S$=CHR$(243) AND TK<3 THEN FR=FR+1:GOTO 20
230 GOTO 140
240 DEF MOVE(0)=SPRITE(0,N,1,8,0,0)
250 POSITION 0,X*8+16,Y*8+24:MOVE 0
260 X=X+CX:Y=Y+CY
280 IF SCR$(X+1,Y+1)<>" " THEN LOCATE X+1,Y+1:PRINT " ":HI=HI+RND(20)+10
290 GOTO 140
500 FOR Y1=2 TO 16 STEP 2:FOR X1=3 TO 25 STEP 2:COLOR X1,Y1,2
510 IF RND(10)=5 THEN LOCATE X1+1,Y1+1:PRINT CHR$(207):GOTO 530
520 IF RND(5)=3 AND Y1<>10 THEN LOCATE X1,Y1:PRINT CHR$(195);CHR$(195):LOCATE X1,Y1+1:PRINT CHR$(195);CHR$(195)
530 NEXT:NEXT
540 X1=RND(12)*2+3:Y1=RND(8)*2+2
590 RETURN
600 FOR I=1 TO 4
610 IF MOVE(I)=-1 OR TC(I)=5 THEN 740
620 IF TC(I)=4 THEN ERA I:TC(I)=5:GOTO 740
625 IF RND(7)>3 THEN K(I)=RND(4)
630 HX=0:HY=0:ON K(I)+1 GOTO 640,650,660,670
640 HX=2:TP=3:GOTO 680
650 HX=-2:TP=7:GOTO 680
660 HY=2:TP=5:GOTO 680
670 HY=-2:TP=1
680 IF SCR$(TX(I)+HX,TY(I)+HY)<>" "THEN 730
700 DEF MOVE(I)=SPRITE(CA,TP,5,8,0,TC(I)):POSITION I,TX(I)*8+16,TY(I)*8+24:MOVE I
710 TX(I)=TX(I)+HX:TY(I)=TY(I)+HY
730 IF TX(I)=X AND TY(I)=Y THEN 800
740 NEXT:RETURN
800 HI=HI-(TP(I)/3+5):IF X+CX<>TX(I) OR Y+CY<>TY(I) AND TC(I)>4 THEN 740
830 IF TP(I)>PO THEN IF RND(TP(I)-PO)>0 THEN 890
840 TC(I)=TC(I)+1:PO=PO+TP(I)/2:IF TC(I)=4 THEN DEF MOVE(I)=SPRITE(10,0,1,255,0,0):POSITION I,TX(I)*8+16,TY(I)*8+24:MOVE I:TK=TK-1
890 GOTO 740
1000 DATA 4,13,11,3,2,14,7,5,15,1,0





