10 '                                                         PROGRAMED' S60/08/16          BY, KEIHIKO.NAKANO      
20 '{M5|M5|M5|M5|M5|M5|M5|M5} セツメイ {M5|M5|M5|M5|M5|M5|M5|M5|M5}
30 ERA7:SPRITEON:CGSET,2:CLS:DEFMOVE(0)=SPRITE(9,0,1,1,0,0):DEFMOVE(1)=SPRITE(9,0,1,1,0,3):DEFMOVE(2)=SPRITE(13,0,1,1,0,3):DEFMOVE(3)=SPRITE(4,0,1,1,0,0):DEFMOVE(4)=SPRITE(14,0,1,1,0,2):DEFMOVE(5)=SPRITE(0,0,1,1,0,0):PALETB 0,14,RND(12)+33,0,0
40 FOR I=0 TO 5:POSITION I,42,I*24+48:MOVE I:NEXT:LOCATE6,4:PRINT"... PLAYER-1 <マリオ> "C1:LOCATE6,7:PRINT"... PLAYER-2 <ルイ-ジ>"C2:LOCATE6,10:PRINT"... ダメ-ジ カイフク ノ モト":LOCATE6,13:PRINT"... タイフウ キョウカ ノ モト":LOCATE6,16:PRINT"... バランス キョウカ ノ モト
50 LOCATE6,19:PRINT"... ダメ-ジ コウカン ノ モト":LOCATE0,1:PRINT"========[BATTLING 2]========":LOCATE0,22:PRINT"=====[PUSH START BOTTUN]===":S=STRIG(0):IFS=0ORS>2THEN50
60 IFS=1THEN80
70 IFS=2THENRUN
80 '{M5|M5|M5|M5|M5|M5|M5} ショキセッテイ {M5|M5|M5|M5|M5|M5|M5}
90 ERA0,1,2,3,4,5:CLS:DEFMOVE(5)=SPRITE(10,0,2,255,0,2):LOCATE7,10:PRINT"BATTLING START":PLAY"M1V15O0T4F3DRECRBAGFEDCRRC9":CGSET1:Z=RND(5)+1:PLAY"T1:T1
100 A=1:D=1:B=0:C=0:E=0:F=0:X=30:Y=20:G=210:H=20:K=0:L=0:T=20:U=20:V=0:W=0:DEFMOVE(7)=SPRITE(15,3,2,128,1,0):POSITION7,58,111:VIEW:GOSUB890
110 ON ERROR GOTO110
120 '{M5|M5|M5|M5|M5|M5|M5} PLAYER-1 {M5|M5|M5|M5|M5|M5}     {M5|M5|M5|M5|M5} セントウキ ノ ソウサ {M5|M5|M5|M5|M5}
130 FOR I=0 TO Z:S=STICK(0):IF S=1 THEN A=A+1
140 IF S=2 THEN A=A-1
150 '{M5|M5|M5|M5|M5} ジェット フンシャ! {M5|M5|M5|M5|M5|M5}
160 S=STRIG(0):IF S<>8 AND V<1THEN220
170 IF(A<3 OR  A=8)AND B>-6 THEN B=B-1
180 IF A>3 AND A<7 AND B<6  THEN B=B+1
190 IF A>1 AND A<5 AND C<6  THEN C=C+1
200 IF A>5 AND A<9 AND C>-6 THEN C=C-1
210 '{M5|M5|M5|M5|M5} タイフウ ハッシャ! {M5|M5|M5|M5|M5}
220 X=X+C:Y=Y+B:IF S=4 AND MOVE(1)=0 THEN DEFMOVE(1)=SPRITE(10,VCT(0),1,99,0,0):POSITION1,X,Y:MOVE1
230 '{M5|M5|M5|M5|M5|M5|M5|M5} ザツヨウ {M5|M5|M5|M5|M5|M5|M5|M5}
240 IF V>0  THEN A=A+(RND(2)*2-1):V=V-1
250 IF X<0  THEN X=0  :C=-C
260 IF X>240THEN X=240:C=-C
270 IF Y<0  THEN Y=0  :B=-B
280 IF A>8  THEN A=1
290 IF A<1  THEN A=8
300 '{M5|M5|M5|M5|M5|M5} ガメン ニ ダス {M5|M5|M5|M5|M5|M5}
310 DEFMOVE(0)=SPRITE(9,A,1,1,1,0):POSITION0,X,Y:MOVE0
320 IF Y>173 THEN Y=173:POSITION5,X,Y:MOVE5:PLAY"O0D0F1:O1D0E":K=K+(ABS(B)+ABS(C))*2:GOSUB890:B=0:C=0:ERA5:IF K>99THEN ERA0:A$="ルイ-ジ":C2=C2+1:POSITION5,X,Y:GOTO1020
330 '{M5|M5|M5|M5|M5|M5|M5} ブツカッタ? {M5|M5|M5|M5|M5|M5|M5}
340 J=CRASH(0):IF J=-1 THEN 420
350 IF J<>7 THEN 380
360 IF MOVE(7)<>0 AND A1=0 THEN V=V+30:GOSUB1050:GOTO380
370 MOVE7:A1=1
380 IF J=4 AND MOVE(4)<>0 THEN GOSUB910
390 IF J=3 AND MOVE(3)<>0 THEN V=V+T:GOSUB1050:ERA3
400 Q=Q+1:IF J=2 AND Q>0 THEN POSITION5,(X+G)/2,(Y+H)/2:MOVE5:SWAP B,E:SWAP C,F:PLAY"O5C1E2:O0D0F1":ERA5:Q=-5
410 '{M5|M5|M5|M5|M5|M5} PLAYER-2 {M5|M5|M5|M5|M5|M5}      {M5|M5|M5|M5} セントウキ ノ ソウサ {M5|M5|M5|M5|M5}
420 S=STICK(1):IF S=1 THEN D=D+1
430 IF S=2 THEN D=D-1
440 '{M5|M5|M5|M5|M5} ジェット フンシャ! {M5|M5|M5|M5|M5}
450 S=STRIG(1):IF S<>8 AND W<1 THEN510
460 IF(D<3 OR  D=8)AND E>-6 THEN E=E-1
470 IF D>3 AND D<7 AND E<6  THEN E=E+1
480 IF D>1 AND D<5 AND F<6  THEN F=F+1
490 IF D>5 AND D<9 AND F>-6 THEN F=F-1
500 '{M5|M5|M5|M5|M5} タイフウ イッシャ! {M5|M5|M5|M5|M5|M5}
510 G=G+F:H=H+E:IF S=4 AND MOVE(3)=0 THEN DEFMOVE(3)=SPRITE(10,VCT(2),1,99,0,3):POSITION3,G,H:MOVE3
520 '{M5|M5|M5|M5|M5|M5|M5|M5} ザツヨウ {M5|M5|M5|M5|M5|M5|M5|M5}
530 IF W>0   THEN D=D+(RND(2)*2-1):W=W-1
540 IF G<0  THEN G=0:F=-F
550 IF G>240THEN G=240:F=-F
560 IF H<0  THEN H=0:E=-E
570 IF D>8  THEN D=1
580 IF D<1  THEN D=8
590 '{M5|M5|M5|M5|M5|M5} ガメン ニ ダス {M5|M5|M5|M5|M5|M5}
600 DEFMOVE(2)=SPRITE(9,D,1,1,1,3):POSITION2,G,H:MOVE2
610 IF H>173 THEN H=173:POSITION5,G,H:MOVE5:PLAY"O0E0G1:O1C0D":L=L+(ABS(E)+ABS(F))*2:GOSUB890:E=0:F=0:ERA5:IF L>99 THEN ERA2:A$="マリオ ":C1=C1+1:POSITION5,G,H:GOTO1020
620 '{M5|M5|M5|M5|M5|M5|M5} ブツカッタ? {M5|M5|M5|M5|M5|M5|M5}
630 J=CRASH(2):IF J=4 AND MOVE(4)<>0 THEN GOSUB960
640 IF J<>7 THEN670
650 IF MOVE(7)<>0 AND A2=0 THEN W=W+30:GOSUB1050:GOTO670
660 MOVE7:A2=1
670 IF J=1 AND MOVE(1)<>0 THEN W=W+U:GOSUB1050:ERA1
680 '{M5|M5|M5|M5|M5} ドウブツ ヲ ダス? {M5|M5|M5|M5|M5}
690 J=RND(99):IF J>0 OR MOVE(4)<>0 THEN790
700 '{M5|M5|M5|M5|M5|M5} ナニ ヲ ダス? {M5|M5|M5|M5|M5|M5}
710 J=RND(7):M=0:N=0:IF J<2 THEN N=14:M=2:GOTO750
720 IF J<4 THEN N=13:M=3:GOTO750
730 IF J<6 THEN N=4
740 '{M5|M5|M5|M5|M5} ドッチ カラ ダス {M5|M5|M5|M5|M5|M5}
750 O=RND(5)+1:J=RND(2):IF J=1 THEN J=3:P=0:GOTO780
760 J=7:P=240
770 '{M5|M5|M5|M5|M5|M5|M5|M5|M5} ダス {M5|M5|M5|M5|M5|M5|M5|M5|M5}
780 DEFMOVE(4)=SPRITE(N,J,O,118,0,M):POSITION4,P,167:MOVE4
790 NEXT
800 IF Y<>173 THEN B=B+1
810 IF H<>173 THEN E=E+1
820 '{M5|M5|M5|M5|M5|M5|M5|M5} ウセナ! {M5|M5|M5|M5|M5|M5|M5|M5}
830 IF MOVE(7)=0 THEN ERA7:A1=0:A2=0
840 IF YPOS(1)>180 OR MOVE(1)=0 THEN ERA1
850 IF YPOS(3)>180 OR MOVE(3)=0 THEN ERA3
860 IF MOVE(4)=0 THEN ERA4
870 GOTO130
880 '{M5|M5|M5|M5|M5|M5|M5|M5} ヒョウジ {M5|M5|M5|M5|M5|M5|M5|M5}
890 LOCATE0,21:PRINT"1-バランス  "T" ","2-バランス  "U" ":LOCATE0,22:PRINT"1-DAMAGE"K" ","2-DAMAGE"L" ":RETURN
900 '{M5|M5|M5|M5|M5} ナニ ヲ トッタノ? {M5|M5|M5|M5|M5}
910 ERA4:PLAY"O3F2GAB:O4C2EGB":S=24-O*4:IF N=13 THEN K=K-S*5
920 IF N=0  THEN SWAP K,L
930 IF N=14 THEN T=T-S:IF T<0 THEN T=0
940 IF N=4  THEN U=U+S
950 GOSUB890:RETURN
960 ERA4:PLAY"O2C2EGB:O5F2GAB":S=24-O*4:IF N=13 THEN L=L-S*5
970 IF N=0  THEN SWAP K,L
980 IF N=14 THEN U=U-S:IF U<0 THEN U=0
990 IF N=4  THEN T=T+S
1000 GOSUB890:RETURN
1010 '{M5|M5|M5|M5} ショウリシャ ハ ダレ? {M5|M5|M5|M5}
1020 ERA1,3,4:MOVE5:PLAY"O0C4ECECECEC:O1D4FDFDFDFDR9RO4":LOCATE0,22:PRINT"        "A$" ノ カチ !!      ":PLAY"O3C5EDFBCBRRCRC:C5EDFBCBRRO2CRC
1030 IF STRIG(0)=1 THEN30
1040 GOTO1030
1050 PLAY"O0C0E4:O1D0F":RETURN